home *** CD-ROM | disk | FTP | other *** search
/ Aminet 44 / Aminet 44 (2001)(GTI - Schatztruhe)[!][Aug 2001].iso / Aminet / dev / src / ChunkyStartup2.lha / ChunkyStartup2K1 / KZoomSprite.i < prev    next >
Text File  |  2001-04-16  |  12KB  |  433 lines
  1. ;    /+===========================================================+/
  2. ;   //                                                           //
  3. ;  //           Modulo-free 8bit Zoom Sprite                    //
  4. ; //                                                           //
  5. ;/+===========================================================+/
  6. ; KZoomSprite.i
  7. ; ->krabob@online.fr<- (Vic Ferry) 01-02-2001
  8. ; 
  9. ; This routines support free-resolution screens+
  10. ; free-resolution texture+
  11. ; free rectangle clipping+
  12. ; coordinate-exchange.
  13. ; 16 bit shifted- fixed comas UV coordinates.
  14. ;
  15. ; phxass command line to make a .o:
  16. ;  phxass KZoomSprite.i I=include: M=68020
  17.  
  18.     ; all macros needed to create some structures.
  19.  incdir include:
  20.     include exec/types.i
  21.  
  22.  
  23.  STRUCTURE ScreenRenderContext,0
  24.  
  25.         APTR src_ChunkyScreen
  26.         LONG src_BytesModulo
  27.         LONG src_ClipX1
  28.         LONG src_ClipY1
  29.         LONG src_ClipX2
  30.         LONG src_ClipY2
  31.  
  32.  LABEL  src_SIZEOF
  33.  
  34.  STRUCTURE TextureContext,0
  35.  
  36.         APTR ttc_ChunkyTexture
  37.         LONG ttc_BytesModulo
  38.         LONG ttc_U1                     ;<<16
  39.         LONG ttc_V1                     ;<<16
  40.         LONG ttc_U2                     ;<<16
  41.         LONG ttc_V2                     ;<<16
  42.  
  43.  LABEL  ttc_SIZEOF
  44.  
  45. ;Following instructions -    fmul.s fp0,fp1
  46. ;                move.l d0,d2
  47. ;                move.l d1,d3
  48. ;                move.l d2,d4
  49. ;                add.l d5,d6
  50. ;                add.l d0,d1 - executes in 3 cycles !!!
  51.  
  52. ; d0.l x1 Rectangle to fit on Chunky Screen.
  53. ; d1.l y1 
  54. ; d2.l x2
  55. ; d3.l y2
  56.  
  57. ; a0.l Screen Render Context (Pointer)
  58. ; a1.l TextureContext (Pointer)
  59.  
  60.         XDEF    KZoomSprite8bit68K
  61.         XDEF    _KZoomSprite8bit68K
  62.  
  63.                 section ZoomSprite,code
  64.  
  65. KZoomSprite8bit68K
  66. _KZoomSprite8bit68K
  67.         movem.l d0-d7/a0-a6,-(sp)
  68.  
  69. ; a2 kept for evt. table.
  70.  
  71. ;  +---------------------------------------------+
  72. ; /             Prepare Height vectors          /
  73. ;+---------------------------------------------+
  74.  
  75.         move.l  d0,a4   ;X1,X2 kept
  76.         move.l  d2,a5
  77.  
  78.         ;  +-------------------------------------+
  79.         ; /     Swap if order Y is not right    /
  80.         ;+-------------------------------------+
  81.         ;d1 Y1
  82.         ;d3 Y2
  83.         move.l  ttc_V1(a1),d5   ;V1
  84.         move.l  ttc_V2(a1),d6   ;V2
  85.  
  86.         cmp.l   d3,d1
  87.         beq     .end            ; exit if 0 lines
  88.         blt     .noswapY
  89.         
  90.                 ; if Y1>Y2 swap values
  91.  
  92.                 move.l  d1,d7
  93.                 move.l  d3,d1
  94.                 move.l  d7,d3
  95.  
  96.                 move.l  d5,d7
  97.                 move.l  d6,d5
  98.                 move.l  d7,d6
  99.  
  100.                 sub.l   #65536,d5   ;last pixel ->first is out (sub logic)
  101.                 sub.l   #65536,d6
  102. .noswapY
  103.  
  104. ; Here:
  105. ; d0: -
  106. ; d1: Y1
  107. ; d2: -
  108. ; d3: Y2
  109. ; d4: -
  110. ; d5: V1
  111. ; d6: V2
  112. ; d7:   -usually calculation-
  113.  
  114. ; a0: RC
  115. ; a1: TXTC
  116. ; a2: kept for table
  117. ; a3: (will be chunky ptr)
  118. ; a4: X1
  119. ; a5: X2
  120.         ;  +-------------------------------------+
  121.         ; /     Clip Up                         /
  122.         ;+-------------------------------------+
  123.  
  124.         move.l  src_ClipY1(a0),d4
  125.         cmp.l   d4,d3
  126.         ble     .end                    ;if out up, exit
  127.         
  128.         cmp.l   d1,d4                   ; have to be clipped or not ?
  129.         ble     .noclip_up              ; >0 had to be clipped
  130.  
  131.                 ;d5= V1 = ...
  132.                 ; a=(d4-d1) (>0)
  133.                 ; b=(d3-d1) (>0)
  134.                 ;Ub=(d6-d5)
  135.                 ;Ua=(Ub/b)*a
  136.                 ;d5 = d5(V1) + Ua
  137.  
  138.                 
  139.                 ;060: scramble these 3*2...
  140.                 move.l  d4,d0   
  141.                 sub.l   d1,d0   ;d0=a (pixel.l)
  142.  
  143.                 move.l  d3,d2           
  144.                 sub.l   d1,d2   ;d2=b (pixel.l)
  145.                 
  146.                 move.l  d6,d7   
  147.                 sub.l   d5,d7   ;d7.l=Ub<<16 (-+)
  148.  
  149.  
  150.                 divs.l  d2,d7   ;Ub/b   divs first because <<16
  151.                 muls.l  d0,d7   ;Ub/b*a
  152.                 
  153.                 add.l   d7,d5   ;V1 Clipped
  154.                 
  155.                 ;d1= Y1=ClipY1          
  156.                 move.l  d4,d1
  157. .noclip_up
  158.         ;  +-------------------------------------+
  159.         ; /     Clip Down                       /
  160.         ;+-------------------------------------+
  161.  
  162.         move.l  src_ClipY2(a0),d4
  163.         cmp.l   d4,d1
  164.         bge     .end                    ;if out down, exit
  165.  
  166.         cmp.l   d3,d4
  167.         bge     .noclip_down
  168.  
  169.                 move.l  d3,d0
  170.                 sub.l   d4,d0   ;d0=a
  171.  
  172.                 move.l  d3,d2
  173.                 sub.l   d1,d2   ;d2=b
  174.  
  175.                 move.l  d6,d7
  176.                 sub.l   d5,d7   ;Ub
  177.  
  178.                 divs.l  d2,d7
  179.                 muls.l  d0,d7   ;a
  180.  
  181.                 sub.l   d7,d6   ;V2-a ... V2 Clipped
  182.  
  183.                 ;d3=ClipY2
  184.                 move.l  d4,d3
  185. .noclip_down
  186.         ;  +-----------------------------------------------------+
  187.         ; /     Set Screen Pointer to Y line & find vector      /
  188.         ;+-----------------------------------------------------+
  189.  
  190.         sub.l   d1,d3           ;d3=Height to render.
  191.  
  192.         sub.l   d5,d6           ;(V2-V1)<<16
  193.         divs.l  d3,d6           ;texture Height vector
  194.         subq.l  #1,d3           ;to use with dbf.w
  195.  
  196.  
  197.         move.l  src_ChunkyScreen(a0),a3
  198.         move.l  src_BytesModulo(a0),d0
  199.         mulu.l  d0,d1           
  200.         add.l   d1,a3           ;a3 point the line to render.
  201.         ;d1 is freed.
  202.  
  203.         
  204.  
  205.  
  206. ;  +---------------------------------------------+
  207. ; /             Prepare Width vectors           /
  208. ;+---------------------------------------------+
  209.  
  210.         move.l  a4,a6
  211.         move.l  a5,d1
  212.  
  213.         move.l  d5,a4
  214.         move.l  d6,a5
  215.  
  216.  
  217. ; Here:
  218. ; d0: -
  219. ; d1: X2
  220. ; d2: -
  221. ; d3: Y lenght to render.
  222. ; d4: -Clip
  223. ; d5: -U1
  224. ; d6: -U2
  225. ; d7: -
  226.  
  227. ; a0: RC
  228. ; a1: TXTC
  229. ; a2: Kept for table
  230. ; a3: Chunky ptr
  231. ; a4: V Start <<16
  232. ; a5: V Vector <<16
  233. ; a6: X1
  234.  
  235.         ;  +-------------------------------------+
  236.         ; /     Swap if order X is not right    /
  237.         ;+-------------------------------------+
  238.         ;d0 X1
  239.         ;d1 X2
  240.  
  241.         move.l  ttc_U1(a1),d5   ;U1
  242.         move.l  ttc_U2(a1),d6   ;U2
  243.  
  244.         cmp.l   d1,a6
  245.         beq     .end            ; exit if 0 lines
  246.         blt     .noswapX
  247.         
  248.                 ; if X1>X2 swap values
  249.  
  250.                 move.l  a6,d7
  251.                 move.l  d1,a6
  252.                 move.l  d7,d1
  253.  
  254.                 move.l  d5,d7
  255.                 move.l  d6,d5
  256.                 move.l  d7,d6
  257.  
  258.                 sub.l   #65536,d5   ;last pixel ->first is out (sub logic)
  259.                 sub.l   #65536,d6
  260. .noswapX
  261.  
  262.         ;  +-------------------------------------+
  263.         ; /     Clip Left                       /
  264.         ;+-------------------------------------+
  265.  
  266.         move.l  src_ClipX1(a0),d4
  267.         cmp.l   d4,d1
  268.         ble     .end                    ;if out up, exit
  269.         
  270.         cmp.l   a6,d4                   ; have to be clipped or not ?
  271.         ble     .noclip_left            ; >0 had to be clipped
  272.  
  273.                 ;d5= V1 = ...
  274.                 ; a=(d4-a6) (>0)
  275.                 ; b=(d1-a6) (>0)
  276.                 ;Ub=(d6-d5)
  277.                 ;Ua=(Ub/b)*a
  278.                 ;d5 = d5(U1) + Ua
  279.  
  280.                 
  281.                 ;060: scramble these 3*2...
  282.                 move.l  d4,d0
  283.                 sub.l   a6,d0   ;d0=a (pixel.l)
  284.  
  285.                 move.l  d1,d2
  286.                 sub.l   a6,d2   ;d2=b (pixel.l)
  287.                 
  288.                 move.l  d6,d7
  289.                 sub.l   d5,d7   ;d7.l=Ub<<16 (-+)
  290.  
  291.  
  292.                 divs.l  d2,d7   ;Ub/b   divs first because <<16
  293.                 muls.l  d0,d7   ;Ub/b*a
  294.                 
  295.                 add.l   d7,d5   ;U1 Clipped
  296.                 
  297.                 ;a6= Y1=ClipY1          
  298.                 move.l  d4,a6
  299. .noclip_left
  300.         ;  +-------------------------------------+
  301.         ; /     Clip Right                      /
  302.         ;+-------------------------------------+
  303.  
  304.         move.l  src_ClipX2(a0),d4
  305.         cmp.l   d4,a6
  306.         bge     .end                    ;if out down, exit
  307.  
  308.         cmp.l   d1,d4
  309.         bge     .noclip_right
  310.  
  311.                 move.l  d1,d0
  312.                 sub.l   d4,d0   ;d0=a
  313.  
  314.                 move.l  d1,d2
  315.                 sub.l   a6,d2   ;d2=b
  316.  
  317.                 move.l  d6,d7
  318.                 sub.l   d5,d7   ;Ub
  319.  
  320.                 divs.l  d2,d7
  321.                 muls.l  d0,d7   ;a
  322.  
  323.                 sub.l   d7,d6   ;V2-a ... V2 Clipped
  324.  
  325.                 ;d1=ClipY2
  326.                 move.l  d4,d1
  327. .noclip_right
  328.  
  329.  
  330.         ;  +-----------------------------------------------------+
  331.         ; /     Set Screen Pointer to X pixel & find vector     /
  332.         ;+-----------------------------------------------------+
  333.  
  334.  
  335.         add.l   a6,a3   ;chunky start x,Y first pixel
  336.         sub.l   a6,d1   ;X2-X1 >0 d1=nb of pixel in width.
  337.  
  338.         sub.l   d5,d6   ;U delta <<16
  339.         divs.l  d1,d6   ;texture Width vector
  340.         swap    d5      ; addx trick for U vect
  341.         swap    d6      
  342.  
  343.         move.l  src_BytesModulo(a0),d0
  344.         sub.l   d1,d0
  345.  
  346.  
  347.         subq.l  #1,d1   ;d1 original width length for loop - a6 freed
  348.  
  349.  
  350.         move.l  ttc_ChunkyTexture(a1),a0        ;no more need for RC.
  351.         move.l  ttc_BytesModulo(a1),a1  
  352.  
  353. ; Here:
  354. ; d0: screen modulo - drawn width
  355. ; d1: X length to render(orig)
  356. ; d2: X length to render(dbf).
  357. ; d3: Y lenght to render.
  358. ; d4: - (things)
  359. ; d5: -U Start <<16     swaped(orig)
  360. ; d6: -U Vector <<16    swaped
  361. ; d7: -U Start <<16     swaped(scan)
  362.  
  363.  
  364. ; a0: Chunky Texture Start.
  365. ; a1: Texture modulo
  366. ; a2: Kept for table
  367. ; a3: Chunky ptr of line.
  368. ; a4: V Start <<16
  369. ; a5: V Vector <<16
  370. ; a6: Chunky Texture "at the line"
  371.  
  372.  
  373. ;  +---------------------------------------------+
  374. ; /     Height Loop                             /
  375. ;+---------------------------------------------+
  376. .loop_height
  377.                 ; find line on texture -> a6
  378.                 move.l  a0,a6
  379.                 move.l  a4,d4   ;V<<16
  380.                 swap    d4      ;V.w
  381.  
  382.                 move.l  a1,d7   ;texture modulo
  383.                 muls.w  d7,d4   ;d4.l= V*txtmodulo
  384.                 add.l   d4,a6           
  385.                                 
  386.                 ; reset U scan
  387.                 move.l  d5,d7           
  388. ;;;;;;;;;;      add.l   #0,d7   ;set "x" to 0. was optimlized by phxass.
  389.                 andi    #$00f,ccr
  390.                 
  391.  
  392.                 ; reset width loop.
  393.                 move.w  d1,d2           
  394. ;  +---------------------------------------------+
  395. ; /             Width Loop                      /
  396. ;+---------------------------------------------+
  397. .loop_width
  398.                 
  399.                         move.b  (a6,d7.w),d4
  400.                         beq.b   .noprint
  401.                         move.b  d4,(a3)
  402. .noprint
  403.                         addx.l  d6,d7   ;U vector
  404.                         addq.l  #1,a3   ;miraculously doesnt reset "x".
  405.  
  406.                 dbf.w   d2,.loop_width
  407. ;  +---------------------------------------------+
  408. ; /             End Width Loop                  /
  409. ;+---------------------------------------------+
  410.  
  411.                 add.l   d0,a3   ; + rest of lines
  412.  
  413.                 ;+ V vector
  414.                 add.l   a5,a4
  415.  
  416.         dbf.w   d3,.loop_height
  417. ;  +---------------------------------------------+
  418. ; /     End of Height Loop                      /
  419. ;+---------------------------------------------+
  420. .end:
  421.         movem.l (sp)+,d0-d7/a0-a6
  422.         rts
  423. ;    /+===========================================================+/
  424. ;   //                                                           //
  425. ;  //                   End                                     //
  426. ; //                                                           //
  427. ;/+===========================================================+/
  428.  
  429.  
  430.  
  431.  
  432.  
  433.